시나공

시험에

나오는 것만

공부한다!

=INDEX($B$4:$B$33,MATCH(LARGE(($A$4:$A$33=$O9)*E$4:E$33,1),($A$4:$A$33=$O9)*E$4:E$33,0)) 

=index(찾을 값이 있는 범위, 행, 열)

입니다. 

match 함수 부분이 행에 해당하는 것이고 

열은 생략 되었으므로 1 로 지정됩니다. 

MATCH(LARGE(($A$4:$A$33=$O9)*E$4:E$33,1),($A$4:$A$33=$O9)*E$4:E$33,0) 

match(찾을 값, 값을 구할 범위, 옵션) 

입니다. 

두번째 인수 부분의 ($A$4:$A$33=$O9)*E$4:E$33 은 값을 구할 범위입니다.  

이 범위는 찾을 값의 위치와 동일하게 사용하게 됩니다. 

문제에서 제시된 것이 

단과대학과 구분별 최대 취업자를 배출한 학과 

이므로 LARGE(($A$4:$A$33=$O9)*E$4:E$33,1) 사용하여 

단과대학과 구분별 최대 취업자를 구한 후 

해당 위치의 값을 두번째 인수의 범위에서 구한 후 

이 값을 행 값으로 지정하게 되는 것입니다. 

=index(찾을 값이 있는 범위, 행, 열) 

에 입력하여 

=INDEX($B$4:$B$33,match 에서 나온 행값, 생략된 값 1) 

로 지정하여 B 열에서 match 에서 나온 행 값에 해당(단과대학과 구분별 최대 취업자)하는 학과를 구하게 되는 것이죠. 

=INDEX($B$4:$B$33,MATCH(LARGE(($A$4:$A$33=$O9)*E$4:E$33,1),($A$4:$A$33=$O9)*E$4:E$33,0)) 

 로 입력한 후 채우기 핸들을 사용하시면 

오른쪽으로 채우기 핸들을 사용했을 때 

=INDEX($B$4:$B$33,MATCH(LARGE(($A$4:$A$33=$O9)*E$4:E$33,1),($A$4:$A$33=$O9)*E$4:E$33,0)) 

=INDEX($B$4:$B$33,MATCH(LARGE(($A$4:$A$33=$O9)*F$4:F$33,1),($A$4:$A$33=$O9)*F$4:F$33,0)) 

=INDEX($B$4:$B$33,MATCH(LARGE(($A$4:$A$33=$O9)*G$4:G$33,1),($A$4:$A$33=$O9)*G$4:G$33,0)) 

...

빨간색으로 표시된 부분이 변경되면서 

인문대학별 건강보험연계, 해외취업자, 창업자, 프리랜서에 해당하는 부분을 찾을 수 있습니다.

채우기 핸들을 아래쪽으로 내리면 

=INDEX($B$4:$B$33,MATCH(LARGE(($A$4:$A$33=$O9)*E$4:E$33,1),($A$4:$A$33=$O9)*E$4:E$33,0))  

=INDEX($B$4:$B$33,MATCH(LARGE(($A$4:$A$33=$O10)*E$4:E$33,1),($A$4:$A$33=$O10)*E$4:E$33,0)) 

사회과학대학으로 변경 되고 

오른쪽으로 채우기 핸들을 사용하시면 

=INDEX($B$4:$B$33,MATCH(LARGE(($A$4:$A$33=$O10)*E$4:E$33,1),($A$4:$A$33=$O10)*E$4:E$33,0)) 

=INDEX($B$4:$B$33,MATCH(LARGE(($A$4:$A$33=$O10)*F$4:F$33,1),($A$4:$A$33=$O10)*F$4:F$33,0)) 

=INDEX($B$4:$B$33,MATCH(LARGE(($A$4:$A$33=$O10)*G$4:G$33,1),($A$4:$A$33=$O10)*G$4:G$33,0))

...

로 사회과학대학별 건강보험연계, 해외취업자, 창업자, 프리랜서에 해당하는 부분을 찾을 수 있습니다.

이렇게 절대참조와 혼합참조를 잘 사용하시면 하나의 식으로 여러 값을 정확하게 나타낼 수 있습니다.