492쪽 3번문제를 풀었습니다.
저는 C3값의 식을
{=MAX(($B$12:$B$27=A3)*($F$12:$F$27))-AVERAGE(($B$12:$B$27=A3)*($F$12:$F$27))}
결과값 : 1,081,925
로 작성하였고 틀렸습니다. ⅰ. 왜 틀린건가요?, average를 꼭 사용해야 하는 이유가 있나요?
정답에 IF를 사용하여 작성하였길래 이를 감안하고 다시 작성하였는데
{=MAX(($B$12:$B$27=A3)*($F$12:$F$27))-AVERAGE(IF($B$12:$B$27=A3,$F$12:$F$27,0))}
결과값 : 1,081,925
앞서 틀린 결과값과 같은 값이 나와 틀렸습니다.
정답은
{MAX(($B$12:$B$27=A3)*($F$12:$F$27))-AVERAGE(IF($B$12:$B$27=A3,$F$12:$F$27))}
결과값 : 574,950
인데 ⅱ. 앞서 했던 식과 차이는 false값에 0을 넣은 차이밖에 없는데, 왜 결과값이 다른지 모르겠습니다.
안녕하세요.
우선,
Average 함수는 조건을 넣을 때, 꼭 IF 함수를 이용해 주셔야 합니다.
조건이 거짓일 경우 if를 사용하면 false를 반환하고, if를 사용하지 않으면 0을 반환하게 됩니다.
Average 함수는 평균을 구하는 함수로 인수에 0 이 포함되면 결과가 달라지기 때문에
if를 사용하여 거짓인 경우 false가 반환되도록 해야 합니다.
MAX 함수는 조건을 넣을 때, if를 사용해도 되고 사용하지 않아도 상관없습니다. 인수 0에 영향을 받지 않기 때문입니다.
0 이 반환되어 값에 영향을 주는 average, min, median, small 함수 등은 반드시 if 문과 함께 사용해야 합니다.
{=MAX(($B$12:$B$27=A3)*($F$12:$F$27))-AVERAGE(IF($B$12:$B$27=A3,$F$12:$F$27,0))}
0을 포함하면, if 함수의 조건이 만족하지 않을 경우 0을 반환해서 AVERAGE 함수의 인수로 넣게 됩니다.
그러면 평균에 영향을 미치게 됩니다.
결국은 AVERAGE 함수에 if를 넣지 않은 것과 같은 결과가 나옵니다.
좋은 하루 보내세요.
-
관리자2019-10-24 20:49:14
안녕하세요.
우선,
Average 함수는 조건을 넣을 때, 꼭 IF 함수를 이용해 주셔야 합니다.
조건이 거짓일 경우 if를 사용하면 false를 반환하고, if를 사용하지 않으면 0을 반환하게 됩니다.
Average 함수는 평균을 구하는 함수로 인수에 0 이 포함되면 결과가 달라지기 때문에
if를 사용하여 거짓인 경우 false가 반환되도록 해야 합니다.
MAX 함수는 조건을 넣을 때, if를 사용해도 되고 사용하지 않아도 상관없습니다. 인수 0에 영향을 받지 않기 때문입니다.
0 이 반환되어 값에 영향을 주는 average, min, median, small 함수 등은 반드시 if 문과 함께 사용해야 합니다.
{=MAX(($B$12:$B$27=A3)*($F$12:$F$27))-AVERAGE(IF($B$12:$B$27=A3,$F$12:$F$27,0))}
0을 포함하면, if 함수의 조건이 만족하지 않을 경우 0을 반환해서 AVERAGE 함수의 인수로 넣게 됩니다.
그러면 평균에 영향을 미치게 됩니다.
결국은 AVERAGE 함수에 if를 넣지 않은 것과 같은 결과가 나옵니다.
좋은 하루 보내세요.